Jak zmusić system Windows do sprawdzania aktualizacji?

Poza zwykłym sposobem korzystania z Windows Update, można wymusić sprawdzenie z wiersza poleceń.

Otwórz wiersz poleceń administratora i uruchom:

C:\> %windir%\system32\wuauclt.exe /detectnow

Wuauclt.exe jest klientem AutoUpdate Windows Update i służy do sprawdzania dostępnych aktualizacji (dla różnych wersji platformy MS Windows) z Microsoft Update.

To nie wymusi instalacji.

Możesz sprawdzić dostępność i zainstalować aktualizacje automatycznie za pomocą skryptu. Będzie to działać zarówno w XP jak i Windows 7.

Istnieje wiele skryptów dostępnych do pobrania, tutaj jest mój :

' Written in 2007 by Harry Johnston, University of Waikato, New Zealand.
' This code has been placed in the public domain. It may be freely
' used, modified, and distributed. However it is provided with no
' warranty, either express or implied.
'
' Exit Codes:
' 0 = scripting failure
' 1 = error obtaining or installing updates
' 2 = installation successful, no further updates to install
' 3 = reboot needed; rerun script after reboot
'
' Note that exit code 0 has to indicate failure because that is what
' is returned if a scripting error is raised.
'

Set updateSession = CreateObject("Microsoft.Update.Session")

Set updateSearcher = updateSession.CreateUpdateSearcher()
Set updateDownloader = updateSession.CreateUpdateDownloader()
Set updateInstaller = updateSession.CreateUpdateInstaller()

Do

  WScript.Echo
  WScript.Echo "Searching for approved updates ..."
  WScript.Echo

  Set updateSearch = updateSearcher.Search("IsInstalled=0")

  If updateSearch.ResultCode <> 2 Then

    WScript.Echo "Search failed with result code", updateSearch.ResultCode
    WScript.Quit 1

  End If

  If updateSearch.Updates.Count = 0 Then

    WScript.Echo "There are no updates to install."
    WScript.Quit 2

  End If

  Set updateList = updateSearch.Updates

  For I = 0 to updateSearch.Updates.Count - 1

    Set update = updateList.Item(I)

    WScript.Echo "Update found:", update.Title

  Next

  WScript.Echo

  updateDownloader.Updates = updateList
  updateDownloader.Priority = 3

  Set downloadResult = updateDownloader.Download()

  If downloadResult.ResultCode <> 2 Then

    WScript.Echo "Download failed with result code", downloadResult.ResultCode
    WScript.Echo

    WScript.Quit 1

  End If

  WScript.Echo "Download complete. Installing updates ..."
  WScript.Echo

  updateInstaller.Updates = updateList

  Set installationResult = updateInstaller.Install()

  If installationResult.ResultCode <> 2 Then

    WScript.Echo "Installation failed with result code", installationResult.ResultCode

    For I = 0 to updateList.Count - 1

      Set updateInstallationResult = installationResult.GetUpdateResult(I)
      WScript.Echo "Result for " & updateList.Item(I).Title & " is " & installationResult.GetUpdateResult(I).ResultCode

    Next

    WScript.Quit 1

  End If

  If installationResult.RebootRequired Then

    WScript.Echo "The system must be rebooted to complete installation."

    WScript.Quit 3

  End If

  WScript.Echo "Installation complete."

Loop

Uruchamiasz go z linii poleceń w ten sposób:

cscript wsusupdate.vbs

Mój skrypt jest tylko minimalnie funkcjonalny, ale może się jeszcze przydać. Istnieją inne tego typu skrypty z wieloma dodatkowymi funkcjami, spróbuj poszukać w Google.

Aby sprawdzić aktualizacje, przejdź do Panelu sterowania, Zabezpieczenia, Windows Update, a następnie kliknij “Sprawdź aktualizacje”.

Innym sposobem na wymuszenie ponownego skanowania aktualizacji jest wyczyszczenie systemu, poprzez usunięcie wszystkich aktualizacji przechowywanych w katalogu %windir%WindowsSoftwareDistributionDownload:

NET STOP wuauserv
    RD /S /Q %windir%\SoftwareDistribution\Download
    NET START wuauserv

Następnie przejdź do Windows Update, i “Sprawdź aktualizacje”. Może to potrwać godzinę, ponieważ sprawdzany jest każdy plik nadający się do aktualizacji na woluminie systemowym (kolejne “Sprawdzenia aktualizacji” będą szybkie). Takie podejście eliminuje błędy, spartaczone aktualizacje i daje czysty, aktualny system, przynajmniej w takim zakresie, w jakim widzi go MS.

Używam narzędzia drugiej strony o nazwie wuinstall do aktualizacji świeżych instalacji windows. dzięki niemu można zautomatyzować cały proces aktualizacji, łącznie z automatycznymi restartami. myślę, że jest to jeden z najszybszych sposobów na uzyskanie świeżego systemu windows bez udziału użytkownika.

Zauważyłem, że jeśli w ramach świeżej instalacji Windows 7 uaktualniłeś IE lub nie uruchomiłeś jeszcze IE i nie odpowiedziałeś na pytania wprowadzające, to Windows Update da ci błąd. Nie znalazłem również sposobu na przełączenie Windows Update na Microsoft Update bez przechodzenia przez GUI, więc ręcznie uruchamiam IE, inicjalizuję go, a następnie konfiguruję Windows Update przez GUI, dzięki czemu mogę przełączyć się na Microsoft Update i uniknąć początkowego błędu. Twój przebieg może się różnić.

Miałem sukces podążając za krokami na tym post , instalując IE8 & WI4.5 , to uruchomi automatyczne aktualizacje, aby rozpocząć pobieranie.