Porównywanie podobnych ciągów tekstowych w Excelu

Można rozważyć użycie dodatku Microsoft Fuzzy Lookup Addin .

Ze strony MS:

Overview

The Fuzzy Lookup Add-In for Excel został opracowany przez Microsoft Research i wykonuje rozmyte dopasowywanie danych tekstowych w programie Microsoft Excel. Może być używany do identyfikacji rozmytych duplikatów wierszy w ramach jednej tabeli lub do rozmytego łączenia podobnych wierszy pomiędzy dwoma różnymi tabelami. Dopasowanie jest odporne na wiele różnych błędów, w tym błędy ortograficzne, skróty, synonimy i dodane/brakujące dane. Na przykład, może wykryć, że wiersze “Mr. Andrew Hill”, “Hill, Andrew R.” i “Andy Hill” odnoszą się do tego samego podmiotu, zwracając wynik podobieństwa wraz z każdym dopasowaniem. Podczas gdy domyślna konfiguracja działa dobrze dla szerokiej gamy danych tekstowych, takich jak nazwy produktów lub adresy klientów, dopasowanie może być również dostosowane do konkretnych domen lub języków.

Przyjrzałbym się użyciu tej listy (tylko angielska sekcja), aby pomóc pozbyć się wspólnych skrótów.

Dodatkowo, możesz rozważyć użycie funkcji, która powie ci, w dokładnych terminach, jak “blisko” są dwa ciągi znaków. Poniższy kod pochodzi z tutaj i dzięki smirkingman .

Option Explicit
Public Function Levenshtein(s1 As String, s2 As String)

Dim i As Integer
Dim j As Integer
Dim l1 As Integer
Dim l2 As Integer
Dim d() As Integer
Dim min1 As Integer
Dim min2 As Integer

l1 = Len(s1)
l2 = Len(s2)
ReDim d(l1, l2)
For i = 0 To l1
    d(i, 0) = i
Next
For j = 0 To l2
    d(0, j) = j
Next
For i = 1 To l1
    For j = 1 To l2
        If Mid(s1, i, 1) = Mid(s2, j, 1) Then
            d(i, j) = d(i - 1, j - 1)
        Else
            min1 = d(i - 1, j) + 1
            min2 = d(i, j - 1) + 1
            If min2 < min1 Then
                min1 = min2
            End If
            min2 = d(i - 1, j - 1) + 1
            If min2 < min1 Then
                min1 = min2
            End If
            d(i, j) = min1
        End If
    Next
Next
Levenshtein = d(l1, l2)
End Function

To, co to zrobi, to powie ci, ile wstawek i usunięć trzeba zrobić z jednym ciągiem, aby dostać się do drugiego. Starałbym się utrzymać tę liczbę na niskim poziomie (a nazwiska powinny być dokładne).

Mam (długą) formułę, której możesz użyć. Nie jest ona tak dobrze dopracowana jak te powyżej - i działa tylko dla nazwiska, a nie pełnego imienia - ale może ci się przydać.

Więc jeśli masz wiersz nagłówka i chcesz porównać A2 z B2, umieść to w dowolnej innej komórce w tym wierszu (np. C2) i skopiuj na koniec.

=IF(A2=B2, “EXACT”,IF(SUBSTITUTE(A2,“-”,“ ”)=SUBSTITUTE(B2,“-”,“ ”), “Hyphen”,IF(LEN(A2)>LEN(B2),IF(LEN(A2)>LEN(SUBSTITUTE(A2,B2,“”)), “Whole String”,IF(MID(A2,1, 1)=MID(B2,1,1),1,0)+IF(MID(A2,2,1)=MID(B2,2,1),1,0)+IF(MID(A2,3,1)=MID(B2,3,1),1,0)+IF(MID(A2,LEN(A2),1)=MID(B2,LEN(B2),1),1,0)+IF(MID(A2,LEN(A2)-1,1)=MID(B2,LEN(B2)-1,1),1, 0)+IF(MID(A2,LEN(A2)-2,1)=MID(B2,LEN(B2)-2,1),1,0)&“°”),IF(LEN(B2)>LEN(SUBSTITUTE(B2,A2,“))), "Whole String”,IF(MID(A2,1,1)=MID(B2,1,1),1,0)+IF(MID(A2,2,1)=MID(B2,2,1),1, 0)+IF(MID(A2,3,1)=MID(B2,3,1),1,0)+IF(MID(A2,LEN(A2),1)=MID(B2,LEN(B2),1),1,0)+IF(MID(A2,LEN(A2)-1,1)=MID(B2,LEN(B2)-1,1),1,0)+IF(MID(A2,LEN(A2)-2,1)=MID(B2,LEN(B2)-2,1),1,0)&“°”))))

To zwróci:

• EXACT - jeśli jest to dokładne dopasowanie
• Hyphen - jeśli jest to para nazwisk dwuczłonowych, ale jedno ma myślnik, a drugie spację
• Whole string - jeśli całe jedno nazwisko jest częścią drugiego (np. jeśli Smith stał się French-Smith)

Po tym poda stopień od 0° do 6° w zależności od liczby punktów porównania między nimi. (tzn. 6° porównuje lepiej).

Jak już mówiłem, jest to trochę zgrubna i gotowa metoda, ale mam nadzieję, że pozwoli Ci znaleźć się w odpowiednim miejscu.

Szukałem czegoś podobnego. Znalazłem poniższy kod. Mam nadzieję, że pomoże to następnemu użytkownikowi, który przyjdzie na to pytanie

Zwraca 91% dla Abrakadabra / Abrakadabra, 75% dla Hollywood Street/Hollyhood Str, 62% dla Florencji/Francji i 0 dla Disneylandu

Powiedziałbym, że jest wystarczająco blisko tego, co chciałeś :)

Public Function Similarity(ByVal String1 As String, _
    ByVal String2 As String, _
    Optional ByRef RetMatch As String, _
    Optional min_match = 1) As Single
Dim b1() As Byte, b2() As Byte
Dim lngLen1 As Long, lngLen2 As Long
Dim lngResult As Long

If UCase(String1) = UCase(String2) Then
    Similarity = 1
Else:
    lngLen1 = Len(String1)
    lngLen2 = Len(String2)
    If (lngLen1 = 0) Or (lngLen2 = 0) Then
        Similarity = 0
    Else:
        b1() = StrConv(UCase(String1), vbFromUnicode)
        b2() = StrConv(UCase(String2), vbFromUnicode)
        lngResult = Similarity_sub(0, lngLen1 - 1, _
        0, lngLen2 - 1, _
        b1, b2, _
        String1, _
        RetMatch, _
        min_match)
        Erase b1
        Erase b2
        If lngLen1 >= lngLen2 Then
            Similarity = lngResult / lngLen1
        Else
            Similarity = lngResult / lngLen2
        End If
    End If
End If

End Function

Private Function Similarity_sub(ByVal start1 As Long, ByVal end1 As Long, _
                                ByVal start2 As Long, ByVal end2 As Long, _
                                ByRef b1() As Byte, ByRef b2() As Byte, _
                                ByVal FirstString As String, _
                                ByRef RetMatch As String, _
                                ByVal min_match As Long, _
                                Optional recur_level As Integer = 0) As Long
'* CALLED BY: Similarity *(RECURSIVE)

Dim lngCurr1 As Long, lngCurr2 As Long
Dim lngMatchAt1 As Long, lngMatchAt2 As Long
Dim I As Long
Dim lngLongestMatch As Long, lngLocalLongestMatch As Long
Dim strRetMatch1 As String, strRetMatch2 As String

If (start1 > end1) Or (start1 < 0) Or (end1 - start1 + 1 < min_match) _
Or (start2 > end2) Or (start2 < 0) Or (end2 - start2 + 1 < min_match) Then
    Exit Function '(exit if start/end is out of string, or length is too short)
End If

For lngCurr1 = start1 To end1
    For lngCurr2 = start2 To end2
        I = 0
        Do Until b1(lngCurr1 + I) <> b2(lngCurr2 + I)
            I = I + 1
            If I > lngLongestMatch Then
                lngMatchAt1 = lngCurr1
                lngMatchAt2 = lngCurr2
                lngLongestMatch = I
            End If
            If (lngCurr1 + I) > end1 Or (lngCurr2 + I) > end2 Then Exit Do
        Loop
    Next lngCurr2
Next lngCurr1

If lngLongestMatch < min_match Then Exit Function

lngLocalLongestMatch = lngLongestMatch
RetMatch = ""

lngLongestMatch = lngLongestMatch _
+ Similarity_sub(start1, lngMatchAt1 - 1, _
start2, lngMatchAt2 - 1, _
b1, b2, _
FirstString, _
strRetMatch1, _
min_match, _
recur_level + 1)
If strRetMatch1 <> "" Then
    RetMatch = RetMatch & strRetMatch1 & "*"
Else
    RetMatch = RetMatch & IIf(recur_level = 0 _
    And lngLocalLongestMatch > 0 _
    And (lngMatchAt1 > 1 Or lngMatchAt2 > 1) _
    , "*", "")
End If

RetMatch = RetMatch & Mid$(FirstString, lngMatchAt1 + 1, lngLocalLongestMatch)

lngLongestMatch = lngLongestMatch _
+ Similarity_sub(lngMatchAt1 + lngLocalLongestMatch, end1, _
lngMatchAt2 + lngLocalLongestMatch, end2, _
b1, b2, _
FirstString, _
strRetMatch2, _
min_match, _
recur_level + 1)

If strRetMatch2 <> "" Then
    RetMatch = RetMatch & "*" & strRetMatch2
Else
    RetMatch = RetMatch & IIf(recur_level = 0 _
    And lngLocalLongestMatch > 0 _
    And ((lngMatchAt1 + lngLocalLongestMatch < end1) _
    Or (lngMatchAt2 + lngLocalLongestMatch < end2)) _
    , "*", "")
End If

Similarity_sub = lngLongestMatch

End Function

Ten kod skanuje kolumnę a i kolumnę b, jeśli znajdzie jakiekolwiek podobieństwo w obu kolumnach, pokazuje je na żółto. Możesz użyć filtra kolorów, aby uzyskać ostateczną wartość. Nie dodałem tej części do kodu.

Sub item_difference()

Range("A1").Select

last_row_all = Range("A65536").End(xlUp).Row
last_row_new = Range("B65536").End(xlUp).Row

Range("A1:B" & last_row_new).Select
With Selection.Interior
    .Pattern = xlSolid
    .PatternColorIndex = xlAutomatic
    .Color = 65535
    .TintAndShade = 0
    .PatternTintAndShade = 0
End With

For i = 1 To last_row_new
For j = 1 To last_row_all

If Range("A" & i).Value = Range("A" & j).Value Then

Range("A" & i & ":B" & i).Select
With Selection.Interior
    .Pattern = xlSolid
    .PatternColorIndex = xlAutomatic
    .ThemeColor = xlThemeColorDark1
    .TintAndShade = 0
  .PatternTintAndShade = 0
End With

End If
Next j
Next i
End Sub

Chociaż moje rozwiązanie nie pozwala na identyfikację bardzo różnych ciągów, to jest przydatne do dopasowania częściowego (substring match), np. “to jest ciąg” i “ciąg” dadzą wynik “pasujący”:

wystarczy dodać “\” przed i po szukanym ciągu do tabeli.

Zwykły wzór:

• vlookup(A1,B1:B10,1,0)
• cerca.vert(A1;B1:B10;1;0)

staje się

• vlookup(“\” & A1 & “\”,B1:B10;1,0)
• cerca. vert(“\” & A1 & “*”;B1:B10;1;0)

“&” jest “krótką wersją” dla concatenate().

Możesz użyć funkcji podobieństwa (pwrSIMILARITY), aby porównać łańcuchy i uzyskać ich procentowe dopasowanie. Możesz rozróżniać wielkość liter lub nie. Będziesz musiał zdecydować, jaki procent dopasowania jest “wystarczająco bliski” dla twoich potrzeb.

Istnieje strona referencyjna pod adresem http://officepowerups.com/help-support/excel-function-reference/excel-text-analyzer/pwrsimilarity/ .

Ale działa całkiem dobrze do porównywania tekstu w kolumnie A z kolumną B.